Tom's Guide | Tom's Hardware | Tom's Games
 |
 |
 |
Here’s the Valentine’s Day 2002 version of DELINDEX BAT. New features:
* It goes to a help/explanation screen instead of just running.
* Gives you a choice of a less or more aggressive version (just enter L or M).
* Options for (A)ddional info, to (V)iew the entire file, or (Q)uit).
* You can just type DELINDEX LESS or DELINDEX MORE to run without help screens.
* Does not delete the Google Tool Bar.The core of delindex.bat is 4 lines for the LESS option and 6 lines for the MORE option, the core being deleting index.dat files that can’t be deleted from within Windows. So why is it 185 lines long? To give you choices, to space it for easy reading, to give you explanations, and options on how to run the program. And the MORE option also deletes other files that clutter and clog up your hard drive. Most of them can be deleted from within Windows, but this does it in one fell swoop. Since, on most drives, a file will take up 16KB whether it’s one byte long or 16,384 bytes long, I opted for a user friendly, newbie to expert version. Total explanation of all functions is beyond the scope of this note or the internal notes. If you have any questions, go to www.google.com or www.computing.net and search for info on any topic you don’t understand.
INSTALL INSTRUCTIONS: Copy and paste below from the first line with :: to the last line with :: into Notepad or Wordpad or the editor of your choice. You MUST name it (save it as) DELINDEX.BAT and put it on your hard drive in the root (C:\) directory for the V(iew) function to work. (It also runs faster than putting it on your Startup disk). In WinME, You MUST use a Startup Disk to delete index.dat files. (In Win98, you MUST reboot to DOS.) This has been extensively tested in WinME with NO problems on MY system; it probably works in Win98, but some adjustments may be necessary.
This version was written specifically for Computing.net: no line is longer than 78 characters; no box drawing characters or special symbols are used; and, "*" is used as a fill character because this forum truncates extra spaces.
FYI: I found out (the hard way) that when using the WinME Startup Disk you cannot move or (x)copy a long filename because the name gets truncated whether you use 'move "longfilename"' or 'move longfi~1'. I.e., when you get back to Windows, longfilename will have been changed to longfi~1. That made finding a way of deleting all the contents of c:\windows\downlo~1\ without deleting the Google Toolbar a challenge.
I have a version that’s functionally identical to this one but with slightly better aesthetics (ascii box drawing and other special characters instead of "*", and better spacing.) If you want that one, or you’re not sure about using a text editor, download it here: http://briefcase.yahoo.com/delindex. Click on the folder "Get Delindex here". If you want to see the contents before you download it, click on DEL-READ. (DEL-READ and DELINDEX.BAT are identical; with no extension you can read it; with the ".BAT" extension, it immediately goes to download.) To Download, click on "DELINDEX.BAT" and save it in C:\. If you have the Google Toolbar, RIGHT click on "DELYES!", left click "Save Target As...", and in the "Save In" window, type in "C:\" (no quotes) if it isn’t there already. You must rename the file from "DELYES!.txt" (Yahoo adds the ".txt") to just "DELYES!". Thanks to Gene for his post at Computing.net alerting me to the existence Yahoo’s briefcase.
===============================================================================
:: * * * * * * *
:: * WELCOME! *
:: * * * * * * *
@echo off
:: This just makes the program run faster:
c:\windows\smartdrv.exe 2048 16 > nul
cls
echo.
echo * DELINDEX.BAT * Last Revised 2/14/2002 * Written by Renaissance Man *
echo.
if not "%1"=="" echo.
if "%1"=="more" goto MORE
if "%1"=="MORE" goto MORE
if "%1"=="less" goto LESS
if "%1"=="LESS" goto LESS
echo DELINDEX.BAT deletes Index.dat files which keep getting bigger and
echo bigger. These files contain ALL your web surfing history since they were
echo last (re)created, and large index.dat files can cause performance issues
echo with browsing. Index.dat files CANNOT be deleted if Windows is running.
echo.
echo * In Windows 98, you must choose "Reboot into DOS mode."
echo * In Windows Millennium Edition, you must boot up with a Startup
echo * disk; select #3, Start Computer Without CD-ROM support.
echo.
echo DELINDEX gives you a choice of LESS or MORE aggressive versions.
echo ******** ** The LESS option deletes only Index.dat files and TEMP files.
echo ******** ** The MORE option also deletes other unnecessary files.
echo WARNING: The MORE aggressive option deletes COOKIES which contain your
echo ******** IDs and passwords for sites that require you to sign in.
echo ******** ** Record IDs and passwords before using the MORE option. ** To
echo ******** retain cookies use the LESS option. ** If you lost your ability
echo ******** to download, you probably ran the MORE option w/Windows running.
echo ******** To fix, reboot, or go to Start/Run and enter scanregw /opt /fix.
echo.
echo TO RUN DELINDEX: enter L for the LESS option or M for the MORE option.
echo OTHER CHOICES: enter A for ADDITIONAL notes; V to VIEW the entire
choice /n/c:lmavq/t:q,99 contents of this program; or Q to QUIT. Selection:
cls
if errorlevel 5 goto EXIT
if errorlevel 4 goto VIEW
echo.
echo * DELINDEX.BAT * Last Revised 2/14/2002 * Written by Renaissance Man *
echo.
echo.
if errorlevel 3 goto NOTES
if errorlevel 2 goto MORE
if errorlevel 1 goto LESS
::
::
:MORE
::
:: COOKIES and TEMPORARY INTERNET FILES are deleted because they also contain
:: spyware, applets that report your surfing habits back to websites, as well
:: as cookies you may never use again. Some people have tens of thousands (!)
:: of files in the Temporary Internet Files folder; this causes browsing
:: problems. Here's how to keep them from building up: in Internet Explorer,
:: click on Tools/Internet Options; on the Advanced tab check the box (if it
:: isn't already checked) next to "Empty Temporary Internet Files folder when
:: browser is closed," click on Apply and OK.
::
deltree /y c:\history
deltree /y c:\windows\cookies
::
:: TESTS for presence of GOOGLE TOOLBAR.
if not exist c:\windows\downlo~1\google*.* deltree /y c:\windows\downlo~1\
if not exist c:\windows\downlo~1\google*.* goto CONTINUE
attrib -h c:\windows\downlo~1\*.* > nul
attrib -r c:\windows\downlo~1\*.* > nul
attrib +r c:\windows\downlo~1\google*.* > nul
if not exist c:\DELYES! echo *** Press Y and then press Enter ***
if not exist c:\DELYES! del c:\windows\downlo~1\*.*>nul
if not exist c:\DELYES! goto continue
del c:\windows\downlo~1\*.* nul
:CONTINUE
attrib -r c:\windows\downlo~1\google*.* > nul
deltree /y c:\windows\history
deltree /y c:\windows\recent
deltree /y c:\windows\tempor~1
if exist c:\windows\locals~1\tempor~1 deltree /y windows\locals~1\tempor~1\
::
::
:: The next 4 lines delete the contents of the Windows Update folder
:: except for wuhistv3.log, the Windows Update history log.
:: Recommended by Microsoft; see KB article Q193385.
::
if not exist c:\progra~1\window~2\wuhistv3.log goto NOHISLOG
move /y c:\progra~1\window~2\wuhistv3.log c:\>nul
if errorlevel 0 if not errorlevel 1 deltree /y c:\progra~1\window~2\ > nul
move /y c:\wuhistv3.log c:\progra~1\window~2\>nul
:NOHISLOG
::
::
:: All Picture files (e.g., "My Pictures") which display thumbnails have a
:: Thumbs.db file that's never resized, even when you delete some (or all)
:: pictures. Windows recreates these files whenever you go back into the
:: picture folder(s). They can be deleted from within Windows.
::
:: Both [path] statements must be the same.
:: Keep the following line as a sample.
:: if exist [path]\thumbs.db del [path]\thumbs.db>nul
:: These are my paths; change them to yours. No harm if you don't.
::
if exist c:\mypict~1\thumbs.db del c:\mypict~1\thumbs.db>nul
if exist c:\mydocu~1\mypict~1\thumbs.db del c:\mydocu~1\mypict~1\thumbs.db>nul
::
::
:: This saves some resources on restart, and about 1MB of disk space. This
:: file is supposed to be rebuilt on restart; on my system it takes days!
:: Rebuilding this file corrects problems with icons not displaying correctly.
if exist "c:\windows\ShellIconCache" deltree /y "c:\windows\ShellIconCache"
goto END
::
::
:LESS
::
del c:\windows\cookies\index.dat
del c:\windows\tempor~1\content.ie5\index.dat
del c:\windows\history\history.ie5\index.dat
del c:\windows\history\history.ie5\mshist~1\index.dat
goto END
::
::
:NOTES
::
echo This program originally deleted only index.dat files. It was expanded
echo with the MORE option to delete other unnecessary files, since a system
echo runs better with fewer files. Folders that Windows recreates are now
echo deleted; folders that are not recreated have their contents deleted.
echo.
echo SUGGESTIONS: ** Don't modify this file unless you REALLY know what you're
echo doing, and back up the original batch file before you tinker with it.
echo ** Defragment your hard drive after using the MORE option for the first
echo time, since this program may free up a lot of disk space. ** Run DELINDEX
echo at least monthly, more often if you use the web often and/or heavily.
echo ** Put this in C:\ for V(iew) to work; it also runs faster. ** TO RUN: In
echo WinME at A:\ (Win98 at C:\), type C:\DELINDEX. ** To run this program
echo without notes or options, type C:\DELINDEX LESS or DELINDEX MORE.
echo ** If you have the Google toolbar: to run DELINDEX MORE without user
echo input, open Notepad, enter ONLY the letter Y and save as DELYES! in C:\.
echo.
echo I wrote this in January 2001 and revised it many times, based on my own
echo experience and the suggestions of others, particularly PCWorld and the
echo Computing.net forum, with special thanks to "newgrl". --Renaissance Man
echo.
goto EXIT
::
::
:VIEW
type c:\delindex.bat|more
goto exit
::
::
:END
::
:: Do not comment out the next two lines; it's safe to delete these files.
:: These are temporary files that should have been deleted by the programs
:: that put them there.
::
deltree /y c:\temp\>nul
deltree /y c:\windows\temp\>nul
::
::
echo.
echo.
echo *** In Windows ME, remove any floppy & press Ctrl-Alt-Delete
echo *** In Windows 98, type WIN, and press Enter
echo.
::
::
:EXIT
:: If you're adept and comfortable with editing, add these 6 lines at the end
:: of the AUTOEXEC.BAT file on your Win ME Startup Disk (without the ::)
:: echo.
:: choice /T:n,15 " ** Run DELINDEX? "
:: echo.
:: if errorlevel==2 goto NODEL
:: If "%config%"=="NOCD" c:\delindex.bat
:: :NODEL
:: You can add the LESS or MORE option after C:\delindex.bat in line 5 above.
:: Then, if you pick option 3, you are given a choice to run DELINDEX.
:: Delindex.bat must be on your hard drive in the root C:\ folder.
::
:: Post suggestions, comments, improvements, questions, or problems on the
:: Windows ME forum at www.computing.net with DELINDEX as the subject.
::
Why are you deleting \Downloaded Program Files.
You reference a MS note, but it says to do this ONLY if you are having problems.If you delete these files, it means the next time you visit the site that put them there (like MS or House Call AV), they get DOWNLOADED again.
These are NOT junk files and shouldn't be deleted!
0 
Most spyware is imbedded in freeware or shareware programs. Some of it is in cookies, stored in both the Cookies and Temporary Internet Files folders. Some Trojans and Worms get into your system via the Downloaded Program Files. Just because I’m paranoid doesn’t mean they’re not out to get you, too!
“About cookies: Netscape Navigator and Internet Explorer will still send out existing cookies even after disabling cookies in the browser settings. You must manually delete any/all cookie files on your system to eliminate being tracked by third-party ad networks or spyware or adware providers.” [Fromsimplythebest.net]
http://grc.com/optout.htm
http://www.spychecker.com
http://www.lsfileserv.com/faq.html
http://www.zdnet.com/products/stories/reviews/0,4161,2612053,00.html
http://www.simplythebest.net/info/spyware.html
http://www.cexx.org/problem.htm
http://www.wired.com/news/privacy/0,1848,49430,00.html
0
All questions are welcome, but if you don't like DELINDEX.BAT or disagree with the basis on which I wrote it, the answer is simple: do NOT use it!
Before there are too many other posts that say "Why did you..." or "You shouldn't...," please be reminded of what I said in my original post:
"Total explanation of all functions is beyond the scope of this note or the internal notes. If you have any questions, go to www.google.com or www.computing.net and search for info on any topic you don’t understand."
Jeez!
0
Fantastic effort Renaissance Man !
Take me a while to go through it all and digest - so will post any comments later.
Thanks....Viking
0
Re: Hmmm -- What if you have tons of stuff in Downloaded Program Files for sites you will never visit again? Should you keep it forever to avoid ever having to download something from a site you do visit often?
You're welcome jFrOg, Trev, and Viking. BTW, the best way to "Go through it all" is to download it and either look at it in a text editor or use the view option. If anyone is not too familiar with DOS, it may be a little hard to figure out what the heck everything means. But it works. If anyone's nervous about using it, scan it for viruses (I already did) and use the LESS option, which is almost benign.
You cannot see most index.dat files in Windows. Open a DOS window and just look at the size of these files:
c:\windows\cookies\index.dat
c:\windows\tempor~1\content.ie5\index.dat
c:\windows\history\history.ie5\index.dat
c:\windows\history\history.ie5\mshist~1\index.datRecreated, they are 16 or 32 KB.
If you want to know what they contain, download Spider from http://www.fsm.nl/ward/ to see your web surfing history.
0
Glad to get hold of the update. Thanks again Renaissance Man.
For those who wish to keep certain things you can always edit out that line from the batch file. If there is something your not sure about do as Renaissance Man suggested and search google or computing.net for more information.
Spider.....
This thing saved my life last night (not really :). I stumbled upon a great site two nights ago and could not for the life of me remember the url or even the sites title or what search terms at google brought it up. I was able via spider to track myself step by step until i found the right one.
0
Hi Renaissance Man, great job!
Just a couple of questions on the first DELINDEX.BAT file a few weeks ago I had to edit out the line
(deltre/y c:\windows\downlo~1\) becuase it was deleting the Temporary Download folder no big deal as it would come back anyway but what line if any would that be this time? If there is one, as I hanve not run the new one yet. Also the last one was just copied on to my start up disk and ran from booting up, is this one the same? and why does it get put on the hard drive in C:\
sorry if I'm making something simple seem hard, I'm just really new to this.
Thanks Snap
0
Awesome! however this newbie is afraid of it. How can I download onto a couple of floppies the light one/and the aggressive one? dos scares me!!
0
Forgot to mention why are your posts so hard to read on my machine.. i have to scroll to the right and by the time i get to the next line i forget where i am.. is it my computer?? I have a 19 inch mon?? thansk
0
Gerri, change your screen resolution to 1024X768 and you wont have to scroll to the right.
The forum stretches for cutNpaste. If you scroll up to Ren's reply in response 4 You will notice a slight difference in width also.
0
Shutmeup^or Shutmedown^ it did not help the print went so small I went to View and brought it back up and still went to the right ..off the screen.. thanks for the help anyhow..
0
Finally got around to trying out the Valentines day version. WoW! Thanks again.
Not sure whats going on Gerri.. I have a 19" monitor set at 1024X768 with the text in ie set to medium. I guees it depends on a number of things.
0
I am all for getting rid of junk, do I just download it, and do what you said, and this is for Windows Me, except I have IE 6, is it for that also, in the post above I see IE5 not IE 6. Sue
0
The prior Delindex.bat had this line:
** deltree/y c:\windows\downlo~1
There were some problems with that as indicated in a prior post. The correct (current) line is:
** deltree/y c:\windows\downlo~1\
The backslash at the end means the contents (only) are deleted, not the entire folder.As for scrolling left to right: The long line of = forces the post to be that wide. There are reasons for/against; Gerri obviously stated a reason against. The reason for is that I did not want the lines in the batch file to wrap. The line of = is 79 characters long, one more than the longest line of the batch file. However the actual post is in proportional type (while DOS is like the window you type in to post, i.e., monospaced), so the lines in the batch file appear much shorter than the 79 character line length. I guess I could try to make the = line shorter; I'm not sure how much shorter I can make it without the batch file lines wrapping. Gerri- do you have to scroll only for the notes above the batch file, or the batch file also? If it’s really a problem, you could cut and paste the entire post into a Word document, turn hyphenation off, and use Courier New, and set the margins so the line length is not more than 79 or 80 characters long.
My 15" Dell laptop screen has a resolution of 1024x768, and the post all fits on one screen (width); I'm sorry not to have realized that it would affect those with lower screen resolution. I think the bizarre thing is that how much you see on your screen has nothing to do with screen size, only resolution!
There is no "light one and one aggressive one" - it's all in one program, and the choice of which option to use is YOURS!
Also, I recommend you put it on the root directory (C:\) of your hard drive. It runs MUCH faster that way, and the V(iew) option (to look at the contents without running it or opening it up in a text editor) is written for installation on C:\, as is the option to look for the Google toolbar without user input. I ran my (old) Delindex from my StartUp disk also, but after running it from C:\, I decided that was the way to go. There is NO functional difference between running it from A:\ or C:\ except speed. If anyone REALLY wanted to only run it from the StartUp disc (why?) you could change the lines that refer to C:\DELINDEX and C:\DELYES! to either eliminate the C:\, or change the C:\ to A:\.
If you really want to download it onto a floppy, that’s your choice. You only need one. The file is 7656 bytes (cut and paste) or 8270 (download, slightly different, as noted in the original post). But if you’re “afraid of DOS” put it on C:\ where you don’t have to tinker with it to make it fully functional.
I do not have IE6 - I have IE 5.5 SP2. From prior inquiries, I think the index.dat files reside in the same place for Win 95 and higher, and IE 5 and higher (you could check that for yourself). If anyone else knows, please post back. All the other files are the same (which relate to WinME and not to IE).
I posted a link on the Win9x forum, and the response is more like flaming; the response on this forum is more gratifying. I am always willing to entertain suggestions as to why I should add to (or delete from) this file. BUT - I would rather listen to YOU as to why I should or should not add to/delete from this batch file, rather than to defend what I did do. I use it regularly with no ill effects whatsoever. It’s possible not all systems run the same way. If you want to check out the 9x forum post and responses, go here: http://www.computing.net/windows95/wwwboard/forum/103384.html
Anyway, try it. You’ll like it. I expect your response to be similar to ShutMeUpOrDown:)
Thanks to all for kind words as well as questions.
0
Me, again. I have an SXGA+ screen, and the resolution is 1400x1050, not 1024x768 as I stated above.
0
I have 800x600 and if I position the slide bar properly - can view the entire code/post
on 1 screen.In the 98 forum there in another BAT "author" and I would pose the same comment/question here as well. I wouldn't need it, but many people have set up user profiles - and I have been told MS KB says additional INDEX.DAT's are created there.
Good effort - no, really good. I would alter it, if I was going to use it - but, hey, that is what you stated right upfront.
Want to really go to work on reclaiming MEGS
of disk space?Outlook Express. DELETED ITEMS.DBX
I found mine by accident and did some net searching. Mine was 6 megs "plump". That file is a complete database collection of all the "GET RICH" emails you deleted long ago (of course, ALL the emails you deleted).
Well, just like index.dat - it too can be deleted. Windows rebuilds.The other standard folders (inbox/outbox/sent/draft) can also be deleted. If you created any personal folders,
and you delete the DBX - you will lose anything stored there and they will not be automatically deleted.note:
Run a Google search on Deleted Items.dbx - my post covers bare info - don't just start deleting until you get more info.
0
RE: INTERNET EXPLORER 6
I spoke too soon. The MORE option probably works just fine. But the less option only deletes the index.dat files, and as you can see, three of the four folders have "IE5" as part of the name. I would guess IE6 has "IE6" as part of the folder name. Anyway, if you have IE6, check for folder names (listed under :LESS) and change the appropriate lines. It's very difficult to find these folders in Windows, and even if you find them, most of the index.dat files don't show up. Take a walk through DOS.
You could change and add lines in the less option that would essentially say
* if exist ...IE5\index.dat del ...IE5...
* if exist ...IE6\index.dat del ...IE6...
That way it would work for both IE5 & IE6, assuming IE6 folders have IE6 as part of the name.Since I don't know what IE6 folders are called, all I can say is if you have IE6, use the MORE option or change/add lines to the LESS option.
0
Nice job,Have been looking forward to this.In your instructions above it states that win ME must use start-up disk to delete the index.dat files.Post 16 implies that it wil run faster from c drive,will it still delete the index files from C?Thanks for taking the time to make life a little easier for some of us.I dont like the idea of people tracking my surfing habits either.
0
Thanks for info..I copied all to my word processor and now can read it fine.. the notes/instructions were stretched off to the right and I had to use the bar on the bottom etc.. but Im going to download and let er rip! tnx..
0
There is NO contradiction in using the StartUp disk AND running the file from C:\.
You MUST use the StartUp Disk. That is NOT an option.
At the A:\ prompt the command is simply C:\DELINDEX (with/without MORE/LESS).
That is, when you get to the A:\ prompt you can still run any program from any drive; in this case, you want to execute the program from the fastest drive, which is C:\.
The only reason to use the StartUp disk is to keep Windows from running.
Does this clear thing up a little?
If you cut and paste the original post to read it in your wordprocessor, I forgot to add that the font size probably should be no bigger than 11 pt.
0
Renaissance Man: Thanks for the excellent post. Fast and efficient on Drive C.. and gained many megs back.. I must have had a lot of junk on there.. Nice valentine gift!
0
I have IE6. Paths are:
C:\WINDOWS\TEMPOR~1\CONTENT.IE5
C:\WINDOWS\HISTORY\HISTORY.IE5No ".IE6" in the path(s).
Can you expain why some IE6 installations change to windows\LOCALS\tempor~1\
0
"Can you expain why some IE6 installations change to windows\LOCALS\tempor~1\"
No! But since I knew (but not on my system or from my experience) that some systems do put the TIF in C:\Windows\Locals\ I included that line in the batchfile. Someone who knows more about the vagaries of Windows will have to answer your question.
Robert 451 - if we were all geniuses, none of us would be here. Maybe I can write a pretty good batch file, but all that means is that I was around when the only OS was DOS 5/6/6.2. There's lots about Windows I don't know. That's why I'm here.
Thanks, sekirt. That means that Delindex with either the Less or the More option will work with IE5 / 5.5 /6. That's good to know. I downloaded to Google Toolbar to make sure I could write the program so as not to delete it, but I was not about to download IE6. Your post will help answer questions for IE6 users that I couldn't.
0
Just a thought !
How do you go about making this baby Automated !?I now want it to come on once a week, do it's stuff and maybe do the dishes and cook.
Is it possible to make this an automated batch file ...Is there EVEN such a thing ?? I'm guessing there is.
How the Heck would one go about doing this ( if possible ).
**This is what happens when you eat cheese before bed !**
RM, it works great and I like the start disk autoexec.bat add in ...It's classy.
Viking
0
The thread referred to in response 16, http://www.computing.net/windows95/wwwboard/forum/103384.html, has been deleted.
The original post (mine) was ONLY a link to this post. Many responses asked about, challenged, and countered some of the premises on which I wrote Delindex.bat.
While the Win 9x responses were a little more hostile than I'm used to on the WinME forum, I still thought it was helpful; there were questions and answers that could have helped others understand more about the program.
Why was that thread removed?
0
If you don't have enough info after reading all the above, there's more here:
http://www.computing.net/windowsme/wwwboard/forum/20337.html
0
Renaissance Man
Can you please just give me the batch file
so I can download it, sounds intresting I would like to try it on 2 of my 4 computors,
on the others I have find junk files, but it
wont delete index.dat files what youre doing
seems great.. thanks
PS
for ME & 98
0  |
 |
 |
This post is quite old and has been locked from receiving new replies. Please create a new posting instead.
| Ads by Google |
