I need help with a batch file that will read from a single file called “Userlist.txt” and then create another file based on that list.

I have some of it already but I’m stuck on getting the first token to be listed on the same line in the “addusers.txt” file instead of on separate lines.

The “Userslist.txt file should look like this:
*********Userlist.txt file***********
Joeuser1,Joe Blow, P@ssw0rd,Information about Joe 1
joeuser2,Joe Blow, P@ssw0rd,Information about Joe 2
joeuser2,Joe Blow, P@ssw0rd,Information about Joe 3
*********Userlist.txt file***********

I want to be able to dynamically create an adduser.txt file using the information from the userlist.txt file. The “Adduser.txt file should look like this:

*********Begin Adduser.txt file***********
[USERS]
Joeuser1,Joe Blow, P@ssw0rd,Information about Joe 1
joeuser2,Joe Blow, P@ssw0rd,Information about Joe 2
joeuser2,Joe Blow, P@ssw0rd,Information about Joe 3
[local]
Administrators,,joeuser1,joeuser2,joeuser3
Engineers,,joeuser1,joeuser2,joeuser3
********End Adduser.txt file***************

Currently I have test.bat file
**********Begin test.bat*************
@echo off
Cls

Rem This portion of the script creates the adduserslist.txt file, but I don’t know how to create the
echo [USERS] > D:\Maintenance\adduserlist.txt
for /f "tokens=*" %%A in (D:\Maintenance\Userlist.txt) do (
echo %%A >> D:\Maintenance\adduserlist.txt
)

echo [local] >> D:\Maintenance\adduserlist.txt
echo Administrators, >> D:\Maintenance\adduserlist.txt
for /f "tokens=1 delims=," %%a in (D:\Maintenance\Userlist.txt) do (
echo ,%%a >> D:\Maintenance\adduserlist.txt
)

echo Engineers, >> D:\Maintenance\adduserlist.txt
for /f "tokens=1 delims=," %%a in (D:\Maintenance\Userlist.txt) do (
echo ,%%a >> D:\Maintenance\adduserlist.txt
)

rem d:\Maintenance\addusers /c d:\Maintenance\adduserlist.txt

*******End test.bat file*************

How about creating the string to print out in a variable, and then printing it just once the file.

To make the set work nicely in the for loop something of a trick is needed.

Option 1: Delayed Variable Expansion (http://www.robvanderwoude.com/variableexpansion.html)

****************************
setlocal ENABLEDELAYEDEXPANSION

set string=Administrators
for /f "tokens=1 delims=," %%a in (Userlist.txt) do call set string=!string!,%%a
echo %string% >> adduserlist.txt

...

endlocal
****************************

Option 2: A Function call
****************************
set string=Administrators
for /f "tokens=1 delims=," %%a in (Userlist.txt) do call :make_string %%a
echo %string% >> adduserlist.txt

set string=Engineers
for /f "tokens=1 delims=," %%a in (Userlist.txt) do call :make_string %%a
echo %string% >> adduserlist.txt

rem Exit script
goto :EOF

REM Function
:make_string
set string=%string%,%1
goto :EOF
****************************

cristian23,

Wow, that worked perfect. Thanks for the help

hrh

Just for your info, my scripts does a little bit more. It creates the users, creates directories for each of the users and then grants permissions to the user directories based on the user that owns them.

Here it is:

*******Begin file
@echo off
Cls
setlocal ENABLEDELAYEDEXPANSION
set yes=d:\Maintenance\y.txt
set xcacls_tool=d:\Maintenance\xcacls.exe

echo [USERS] > D:\Maintenance\adduserlist.txt
for /f "tokens=*" %%A in (D:\Maintenance\Userlist.txt) do (
echo %%A >> D:\Maintenance\adduserlist.txt
)

echo [local] >> D:\Maintenance\adduserlist.txt
set string=Administrators,
for /f "tokens=1 delims=," %%a in (Userlist.txt) do call set string=!string!,%%a
set string=!string!,
echo %string% >> adduserlist.txt

set string=ENG_GRP,
for /f "tokens=1 delims=," %%a in (Userlist.txt) do call set string=!string!,%%a
set string=!string!,
echo %string% >> adduserlist.txt

set string=SCM_GRP,
for /f "tokens=1 delims=," %%a in (Userlist.txt) do call set string=!string!,%%a
set string=!string!,
echo %string% >> adduserlist.txt

d:\Maintenance\addusers /c d:\Maintenance\adduserlist.txt

d:

cd D:\Development\users
for /f "tokens=1 delims=," %%A in (D:\Maintenance\Userlist.txt) do (

md D:\Development\users\%%A
md D:\Development\users\%%A\projects
md D:\Development\users\%%A\submit
)


for /f "tokens=1 delims=," %%A in (D:\Maintenance\Userlist.txt) do (
%xcacls_tool% D:\Development\users\%%A /t /g Administrators:f ENG_GRP:r SCM_GRP:r %%A:c < %yes%
)

endlocal
********End file