How do I make a bat that asks the user what
file to render and what ini file to use?

This is the command to use to render in povray 3.1
.............................................
POVRAY +Ifiletorender.pov initouse.ini -D

You could make a batch file where the sintax would be:

filename.bat file_to_render ini_file
Example:
filename.bat filetorender.pov initouse.ini

On inside the batch file, you would use %1 and %2, which represent the first and second parameters passed to the batch file. It would be also good to add a sintax help. Something like this:

@echo off
:: Check for sintax errors
if "%2"=="" for %%? in (echo goto:sintax) do %%? Missing parameter
if not "%3"=="" for %%? in (echo goto:sintax) do %%? Excess of parameters - %3
if not exist %1 for %%? in (echo goto:sintax) do %%? Invalid filename - %1
if not exist %2 for %%? in (echo goto:sintax) do %%? Invalid filename - %2
:: If sintax is valid (both parameters
:: where stated and both exist), execute
:: the command
POVRAY +I%1 %2 -D
goto eof
:: If there's a sintax error, display
:: a help message
:sintax
echo.
echo Sintax: %0 file_to_render ini_file
echo Example: %0 rend.pov start.ini
echo.
:eof

Watch out for line wrapping!

Second solution: if you want something like "Type file to render and hit enter", see my FAQ:

FAQ #06 - Get user input
http://www.batch.hpg.com.br/index.htm#06

-- Leonardo Pignataro - Secret_Doom --

secret_doom@hotmail.com
www.batch.hpg.com.br